changeset 881:618967a008a2

Try to fix autoconf setup
author Mikael Berthe <mikael@lilotux.net>
date Sat, 27 May 2006 17:35:19 +0200
parents ea983a945eba
children c3c2f7a0c5d5
files mcabber/configure.ac mcabber/macros/define_dir.m4
diffstat 2 files changed, 33 insertions(+), 1 deletions(-) [+]
line wrap: on
line diff
--- a/mcabber/configure.ac	Sat May 27 15:59:05 2006 +0200
+++ b/mcabber/configure.ac	Sat May 27 17:35:19 2006 +0200
@@ -115,7 +115,9 @@
 
 # Export $datarootdir to the source tree.
 if test x"${datarootdir}" != x""; then
-    AC_DEFINE_UNQUOTED(DATA_ROOT_DIR, "${datarootdir}", [Data files directory])
+    AC_DEFINE_DIR(DATA_ROOT_DIR, "${datarootdir}", [Data files directory])
+elif test x"${datadir}" != x""; then
+    AC_DEFINE_DIR(DATA_ROOT_DIR, "${datadir}", [Data files directory])
 fi
 
 AC_ARG_ENABLE(debug,
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/mcabber/macros/define_dir.m4	Sat May 27 17:35:19 2006 +0200
@@ -0,0 +1,30 @@
+dnl define_dir.m4
+dnl http://autoconf-archive.cryp.to/ac_define_dir.html
+
+#  AC_DEFINE_DIR(VARNAME, DIR [, DESCRIPTION])
+# This macro sets VARNAME to the expansion of the DIR variable, taking care
+# of fixing up ${prefix} and such.
+# VARNAME is then offered as both an output variable and a C preprocessor
+# symbol.
+
+# Authors
+# Stepan Kasal <kasal@ucw.cz>, Andreas Schwab <schwab@suse.de>,
+# Guido Draheim <guidod@gmx.de>, Alexandre Oliva
+# (Slightly modified -- Mikael Berthe)
+
+AC_DEFUN([AC_DEFINE_DIR], [
+  prefix_NONE=
+  exec_prefix_NONE=
+  test "x$prefix" = xNONE && prefix_NONE=yes && prefix=$ac_default_prefix
+  test "x$exec_prefix" = xNONE && exec_prefix_NONE=yes && exec_prefix=$prefix
+dnl In Autoconf 2.60, ${datadir} refers to ${datarootdir}, which in turn
+dnl refers to ${prefix}.  Thus we have to use `eval' twice.
+  ac_define_dir=`eval echo [$]$2`
+  ac_define_dir=`eval echo [$]ac_define_dir`
+  AC_SUBST($1, "$ac_define_dir")
+  ifelse($3, ,
+    AC_DEFINE_UNQUOTED($1, "$ac_define_dir"),
+    AC_DEFINE_UNQUOTED($1, "$ac_define_dir", $3))
+  test "$prefix_NONE" && prefix=NONE
+  test "$exec_prefix_NONE" && exec_prefix=NONE
+])